*
* AFFICHE UN TEXTE EN HGR
*
* V-1.00 - UPDATE 11/07/90
*

         ORG   $7100
         LST   OFF

DEP      =     $00FC
ARR      =     $00FE
CARAL    =     $1000
CARAH    =     $1080
GRAPL    =     $1130
GRAPH    =     $11F0

A0       LDA   #$00
         STA   DEP
         LDA   #$17
         STA   DEP+1

A0B      JSR   H1
         BCS   A0

         INC   DEP
         LDA   DEP
         BNE   A1
         INC   DEP+1

A1       LDX   #$01
         LDA   $23D0,X
         PHA
         LDA   $27D0,X
         PHA
         LDA   $2BD0,X
         PHA
         LDA   $2FD0,X
         PHA
         LDA   $33D0,X
         PHA
         LDA   $37D0,X
         PHA
         LDA   $3BD0,X
         PHA
         LDA   $3FD0,X
         PHA
         DEX
         PLA
         STA   $3FD0,X
         PLA
         STA   $3BD0,X
         PLA
         STA   $37D0,X
         PLA
         STA   $33D0,X
         PLA
         STA   $2FD0,X
         PLA
         STA   $2BD0,X
         PLA
         STA   $27D0,X
         PLA
         STA   $23D0,X
         INX
         INX
         CPX   #$28
         BNE   A1+2

         LDA   $C000
         BPL   A0B
         BIT   $C010
         RTS

H1       LDY   #$00       ;TEXTE
         LDA   (DEP),Y    ;RETOUR
         BEQ   H2         ;SI 00
         JSR   H3         ;AFFICHE
         CLC
         RTS

H2       SEC
         RTS

* AFFICHE LE TEXTE

H3       SEC              ;SOUSTRAIT A0
         SBC   #$A0       ;POUR L'EQUIVALENCE

H31      TAX              ;TABLE/CARACTERE
         LDA   CARAL,X    ;CARACTERES
         STA   H5+1       ;CORRESPONDANT
         LDA   CARAH,X    ;ADRESSE BASSE
         STA   H5+2       ;ET HAUTE

         LDX   #$B8
H4       LDA   GRAPL,X    ;CHARGE LA LIGNE
         STA   ARR        ;D'ARRIVEE BASSE
         LDA   GRAPH,X    ;ET EVIDEMMENT
         STA   ARR+1      ;HAUTE

H5       LDA   $FFFF      ;AFFICHE
         LDY   #$27       ;SUR LA COLONNE
         STA   (ARR),Y    ;YB
         INC   H5+1       ;BYTE+1
         LDA   H5+1
         BNE   H6
         INC   H5+2
H6       INX              ;LIGNE+1
         CPX   #$FF
         BNE   H4
         RTS              ;RETOUR